Пример расчета цели по весам. Мини-модель QlikView Balanced Scorecard

13.04.201827.12.2017 от Qlik Expert Russia

Contents

1 Введение в суть мини-модели QlikView Balanced Scorecard
2 Скачать пример Balanced Scorecard QlikView в формате zip
3 Примеры реализации Balanced Scorecard из других систем (для разработок в QlikView)
4 Balanced Scorecard – дашборд, поясняющий теорию Сбалансированной системы показателей
5 Обзор реализации Strategic Enterprise Management в QlikView (сторонняя разработка)
- 5.1 Бесплатно скачать проект QlikView “Strategic Enterprise Management”
6 Еще один проект сторонней разработки – QlikView Physician Performance Scorecard.qvw
7 Роберт С. Каплан, Дейвид П. Нортон “Сбалансированная система показателей. От стратегии к действию”

В этой статье будет рассмотрен небольшой Пример расчета цели по весам. Мини-модель QlikView Balanced Scorecard.

Введение в суть мини-модели QlikView Balanced Scorecard

Есть верхнеуровневая цель (Например, Повысить продажи), эта цель достигается путем достижения 4х показателей (например, Увеличить количество звонков, Повысить конверсию в заявку, повысить конверсию заявки в продажу, Повысить количество возврата ушедших клиентов). Это примерные варианты цели и подчиненных подцелей (или показателей).

Мы можем назначить каждому показателю свой вес, который показывает “влияние показателя на верхнеуровневую цель”. Чем больше вес показателя, тем более значимым является показатель и ему нужно уделять больше внимания.

Входные данные QlikView Balanced Scorecard и расчет дерева показателей

Пусть у нас есть табличка текущих значений 4х показателей. Требуется рассчитать цель по весам.

Внизу статьи приведен скрипт расчета и файлы этого демо-примера. Результат расчета в QlikView выглядит так:

Скрипт расчета QlikView Balanced Scorecard

SET vDataDirectory = 'F:\#QlikProject\Дашборд\';

Data:
LOAD Parent_ID,
	 ParentName,
     Element_ID,
     ElementName,
     [Тип показателя],
     [Текущее значение],
     [Целевое значение],
     [Тип значения],
     [Вес] as Weight,
     [Текущее значение]/[Целевое значение] as Percent
FROM
[$(vDataDirectory)Иерархия показателей.xlsx]
(ooxml, embedded labels, table is [Дерево целей]);

HierarchyTable:
Hierarchy (NodeID, ParentID, Node, NodeParent, Node, NodePath, '//', NodeDepth)
Load
	 Element_ID as NodeID,
	 Parent_ID as ParentID,
	 ElementName as Node,
	 ParentName,
	 [Тип показателя],
	 [Текущее значение],
     [Целевое значение],
     [Тип значения],
     Weight,
     Percent,
     Weight*Percent as WPercent
Resident Data;

DROP Table Data;

//Определяем максимальный уровень вложенности
Temp:
LOAD max(NodeDepth) as maxLevel
Resident HierarchyTable;

Let varMaxLevel = Num(Peek('maxLevel', 0, 'Temp'));

DROP Table Temp;


for i=$(varMaxLevel) to 2 Step -1
	LET j=$(i)-1;
	Let varParentNode = 'Node' & '$(j)';
	Let varChildNode = 'Node' & '$(i)';
	
	TempTable:
	LOAD $(varParentNode) as Elem,
		 SUM(WPercent) as CalcPercent
	Resident HierarchyTable
	Where NodeDepth=$(i)
	Group by $(varParentNode);
	
	LEFT JOIN (HierarchyTable)
	LOAD Elem as $(varParentNode),
		 CalcPercent as CWPercent
	Resident TempTable;
	
	NoConcatenate
	HierarchyTableTemp:
	LOAD NodeID,
		 ParentID,
		 Node,
		 Node1,
		 Node2,
		 NodeDepth,
		 NodeParent,
		 NodePath,
		 ParentName,
		 Weight,
		 if(IsNull(Percent),CWPercent,Percent) as Percent,
		 if(NodeDepth=$(j) and IsNull(WPercent),CWPercent*Weight,WPercent) as WPercent,
		 [Тип показателя],
		 [Текущее значение],
		 [Целевое значение],
		 [Тип значения]
	Resident HierarchyTable;
	
	DROP Tables HierarchyTable,TempTable;
	RENAME Table HierarchyTableTemp to HierarchyTable;
	
NEXT i

NoConcatenate
TargetTable:
LOAD NodeID,
	 Node,
	 ParentName,
	 if(ParentName='none',Node,ParentName) as MainGoal,
	 Weight,
	 if((NodeDepth=1 and Percent=''),WPercent,Percent) as Percent,
	 [Тип показателя],
	 [Текущее значение],
	 [Целевое значение],
	 [Тип значения]
Resident HierarchyTable;
	
DROP Tables HierarchyTable;

1

2

3

4

5

6

7